SAP .Net Connector 3.0 - Net Framework 4.0 - Executando uma RFC e lendo os dados de uma tabela - Parte 3

Parte 3

Para encerrar o tutorial veremos como acessar os dados de uma RFC e como gravar dados em uma tabela dentro da RFC. Para isso daremos continuidade ao nosso projeto.

Serei bem direto nessa etapa pois creio que o código fonte fala por si só.

Lendo os dados de uma tabela

1º criei um classe de nome Material para receber os dados da tabela que iremos ler:

Public Class Material
    Private _code As String
    Private _descricao As String
    Private _quantidade As Double

    Public Property Code As String
        Get
            Return _code
        End Get
        Set(value As String)
            _code = value
        End Set
    End Property

    Public Property Descricao As String
        Get
            Return _descricao
        End Get
        Set(value As String)
            _descricao = value
        End Set
    End Property

    Public Property Quantidade As Double
        Get
            Return _quantidade
        End Get
        Set(value As Double)
            _quantidade = value
        End Set
    End Property
End Class

2º criei um método dentro da classe RfcTableReader de nome getMateriais, onde iremos ler os dados da tabela SAP e montar uma lista de materias:


Public Function getMateriais(ByRef rfcFunction As IRfcFunction) As IList(Of Material)
        Try
            'RECUPERANDO A TABELA TB_MATERIAIS DA RFC
            Dim rfcTabMateriais As IRfcTable = rfcFunction.GetTable("TB_MATERIAIS")
            'CRIANDO UMA LISTA QUE IRÁ CONTER DOS DADOS LIDOS DA RFC-TABLE
            Dim itens As IList(Of Material) = New List(Of Material)

            'EXECUTANDO O LOOP DOS DADOS DA TABELA SAP
            For Each row As IRfcStructure In rfcTabMateriais
                Dim it As New Material
                'TESTANDO SE O EXISTE VALOR NA VARIAVEL SAP
                If Not (IsDBNull(row.GetValue("DSCODE"))) Then
                    it.Code = row.GetString("DSCODE")
                End If
                If Not (IsDBNull(row.GetValue("DSDESCRIPT"))) Then
                    it.Descricao = row.GetString("DSDESCRIPT")
                End If
                If Not (IsDBNull(row.GetValue("DSQUANT"))) Then
                    it.Quantidade = row.GetString("DSQUANT")
                End If
                'VERIFICANDO SE O MATERIAL POSSUI CÓDIGO
                If Not String.IsNullOrEmpty(it.Code) Then
                    itens.Add(it) 'ADD REGISTRO A LISTA
                End If
            Next
            Return itens
        Catch exSap As RfcAbapRuntimeException
            Throw New Exception("ABAP error run Time: " & exSap.Message)
        Catch exSap As RfcAbapBaseException
            Throw New Exception("ABAP base error" & exSap.Message)
        Catch ex As Exception
            Throw
        End Try
    End Function

leia atentamente os comentários que estão dentro da função para que você tenha maior conhecimento da mesma, ok?

3º Executando a RFC e lendo os dados da tabela Material utilizando o que criamos até o momento:

Antes alguns detalhes importantes,

Criando uma instancia IRfcFunction, ela serve para executar todos os comandos da RFC e dentro dela estão contidas todas as tabelas, parametros etc dessa função.

No nosso exemplo iremos chamar a RFC "FRC_MATERIAL":

Dim rfcFunction As IRfcFunction = repositorio.CreateFunction("RFC_MATERIAL")

Após chamar a RFC é necessário a passagens dos parametros da função, caso necessário, como data, período, usuário, lote etc, cada RFC possui seus próprios parâmetros.

rfcFunction.SetValue("DATA", Now)

rfcFunction.SetValue("USER", "camilo.correa.silva.silva")

Para finalizar essas observações, após definir a RFC, passar os devidos parâmetros, basta invocar a função, ou executa-la. Para isso você irá utilizar a função "invoke" e passar para ela as configurações de acesso definidas na segunda parte desse tutorial [ 2ª parte ].

rfcFunction.Invoke(dest)

Veja como ficou nosso código:
   Public Sub LerDadosRFC()
        Try
            '1º - MONTAR OS PARAMETROS PARA CONEXÃO SAP
            Dim con As New SAPConnect()
            'A FUNÇÃO REGISTER ABRE A CONEXÃO COM SAP
            RfcDestinationManager.RegisterDestinationConfiguration(con)
            Dim dest As RfcDestination = RfcDestinationManager.GetDestination("homologacao")
            Dim repositorio As RfcRepository = dest.Repository
            Try
                'CHAMANDO A RFC - PASSANDO PARAMETROS
                Dim rfcFunction As IRfcFunction = repositorio.CreateFunction("RFC_MATERIAL")

                'PASSANDO OS PARAMETROS DE LEITURA DA RFC
                rfcFunction.SetValue("DATA", Now)
                rfcFunction.SetValue("USER", "camilo.correa.silva.silva")

                'EXECUTANDO A RFC
                rfcFunction.Invoke(dest)

                'CHAMANDO A FUNÇÃO QUE LÊ OS DADOS CONTIDOS NA TABLE DA RFC
                Dim materiais As IList(Of Material) = getMateriais(rfcFunction)

            Catch exSap As RfcAbapRuntimeException
                Throw New Exception("ABAP error run Time: " & exSap.Message)
            Catch exSap As RfcAbapBaseException
                Throw New Exception("ABAP base error" & exSap.Message)
            Catch ex As Exception
                Throw
            Finally
                'FECHA A CONEXÃO COM SAP
                RfcDestinationManager.UnregisterDestinationConfiguration(con)
            End Try

        Catch exSap As RfcCommunicationException
            Throw New Exception("Falha na comenicação com SAP: " & exSap.Message)
        Catch exSap As RfcLogonException
            Throw New Exception("Falha no Login: " & exSap.Message)
        Catch ex As Exception
            Throw New Exception("Erro: " & vbCrLf & ex.Message)
        End Try
    End Sub

4º Gravando dados em uma tabela do SAP

As funções para leitura e gravação são bem parecidas e intuitivas, por exemplo, para se ler um campo de uma tabela SAP getValue("NOME DO CAMPO"), para se escrever em um campo, setValue("NOME DO CAMPO", valor). 
Dito isso, existe apenas um comando a mais que deve ser inserido para gerar uma nova linha na tabela SAP antes de inserirmos os valores, que é o comando "Append()"

Veja logo baixo como ficou nosso código de gravação em uma tabela SAP:

 Public Sub GravarDadosRFC(ByVal materiais As IList(Of Material))
        Try

            '1º - MONTAR OS PARAMETROS PARA CONEXÃO SAP
            Dim con As New SAPConnect()
            'A FUNÇÃO REGISTER ABRE A CONEXÃO COM SAP
            RfcDestinationManager.RegisterDestinationConfiguration(con)
            Dim dest As RfcDestination = RfcDestinationManager.GetDestination("homologacao")
            Dim repositorio As RfcRepository = dest.Repository
            Try
                'CHAMANDO A RFC - PASSANDO PARAMETROS
                Dim rfcFunction As IRfcFunction = repositorio.CreateFunction("RFC_MATERIAL")

                'PASSANDO OS PARAMETROS DE LEITURA DA RFC
                rfcFunction.SetValue("DATA", Now)
                rfcFunction.SetValue("USER", "camilo.correa.silva.silva")

                'INSTANCIANDO A TABELA MATERIAL
                Dim rfcTabMateriais As IRfcTable = rfcFunction.GetTable("TB_MATERIAIS")

                'INSERINDO OS REGISTROS DA TABELA DO SAP
                For Each material As Material In materiais
                    'CRIAR UM NOVO REGISTRO NA TABELA
                    rfcTabMateriais.Append()
                    'PASSANDO OS VALORES PARA TABLE
                    rfcTabMateriais.SetValue("DSCODE", material.Code)
                    rfcTabMateriais.SetValue("DSDESCRIPT", material.Descricao)
                    rfcTabMateriais.SetValue("DSQUANT", material.Quantidade)
                Next

                'EXECUTANDO A RFC e INSERINDO OS VALORES
                rfcFunction.Invoke(dest)
              
            Catch exSap As RfcAbapRuntimeException
                Throw New Exception("ABAP error run Time: " & exSap.Message)
            Catch exSap As RfcAbapBaseException
                Throw New Exception("ABAP base error" & exSap.Message)
            Catch ex As Exception
                Throw
            Finally
                'FECHA A CONEXÃO COM SAP
                RfcDestinationManager.UnregisterDestinationConfiguration(con)
            End Try

        Catch exSap As RfcCommunicationException
            Throw New Exception("Falha na comenicação com SAP: " & exSap.Message)
        Catch exSap As RfcLogonException
            Throw New Exception("Falha no Login: " & exSap.Message)
        Catch ex As Exception
            Throw New Exception("Erro: " & vbCrLf & ex.Message)
        End Try
    End Sub



Conclusão

Podemos perceber que para fazer uma integração com SAP via RFC é bem simples. Para isso você deve saber meia dúzia de comandos e ter uma código bem estruturado.

Espero que tenha conseguido ajudar pessoas que como eu tiveram dificuldade de fazer sua primeira integração .Net com SAP.

Se existir alguma dúvida sobre meu código basta me escrever ou postar um comentário, ok?

Para finalizar, como eu havia prometido, segue o link para download da solução que desenvolvemos para esse tutorial:

[ Solução .Net 4.0, visual Studio 2010 RFC Tutorial ]
senha para desconpacta: besaleel.blogspot.com.br

SAP .Net Connector 3.0 - Net Framework 4.0 - Executando uma RFC e lendo os dados de uma tabela - Parte 2

PARTE 2

A segunda parte do tutorial trata da conexão com SAP utilizando as bibliotecas que incorporamos em nosso projeto.

De forma bem direta iremos iniciar criando em nossa solução um arquivo de configuração contendo as informações necessárias para nós realizarmos um conexão bem sucedida com SAP, ok?

Esse arquivo de configuração é o app.config, se fosse um projeto web poderia ser o web.config, ok?

Dentro das tags vamos guardar nossas informações de configuração.

Agora vamos criar as funções necessárias para se conectar com o SAP

Na realidade iremos precisar apenas de criar um classe e implementar os métodos de uma interface do sapncon de nome IDestinationConfiguration. Os métodos exigidos pela classe que iremos implementar são responsáveis pelo controle da conexão com o SAP.

São eles:
GetParameters(), IDestinationConfiguration_ChangeEventsSupported(), ChangeEventsSupported(), ConfigurationChanged()

Iremos trabalhar apenas no GetParameters, veja a implementação da classe logo abaixo:
Imports System.Configuration
Imports SAP.Middleware.Connector

Public Class SAPConnect
Implements IDestinationConfiguration

''' ''' Monta a estrutura de conexão com o SAP de acordo com o "DestinationName" que pode ser tratado com servidor,
''' em nosso caso temos um servidor de Homologação de dados e um de Produção.
'''
''' Nome da Instancia ou Servidor
''' Destino da conexão
''' Besaleel 2014-08-01
Public Function GetParameters(ByVal destinationName As String) As RfcConfigParameters Implements IDestinationConfiguration.GetParameters
Try
Dim conf As RfcConfigParameters = New RfcConfigParameters()
If destinationName.Equals("homologacao") Then
Dim hostH = ConfigurationManager.AppSettings.Get("ServidorSap")
Dim numbH = ConfigurationManager.AppSettings.Get("NumeroSap")
Dim sysH = ConfigurationManager.AppSettings.Get("SistemaSap")
Dim userH = ConfigurationManager.AppSettings.Get("UsuarioSAP")
Dim passH = ConfigurationManager.AppSettings.Get("PassWordSAP")
Dim clieH = ConfigurationManager.AppSettings.Get("ClienteSAP")
Dim langH = ConfigurationManager.AppSettings.Get("IdiomaSAP")


With conf
.Add(RfcConfigParameters.AppServerHost, hostH)
.Add(RfcConfigParameters.SystemNumber, numbH)
.Add(RfcConfigParameters.SystemIDs, sysH)
.Add(RfcConfigParameters.User, userH)
.Add(RfcConfigParameters.Password, passH)
.Add(RfcConfigParameters.Client, clieH)
.Add(RfcConfigParameters.Language, langH)
End With
Return conf
End If
'PRODUÇÃO
Dim host = ConfigurationManager.AppSettings.Get("ServidorSap")
Dim numb = ConfigurationManager.AppSettings.Get("NumeroSap")
Dim sys = ConfigurationManager.AppSettings.Get("SistemaSap")
Dim user = ConfigurationManager.AppSettings.Get("UsuarioSAP")
Dim pass = ConfigurationManager.AppSettings.Get("PassWordSAP")
Dim clie = ConfigurationManager.AppSettings.Get("ClienteSAP")
Dim lang = ConfigurationManager.AppSettings.Get("IdiomaSAP")


With conf
.Add(RfcConfigParameters.AppServerHost, host)
.Add(RfcConfigParameters.SystemNumber, numb)
.Add(RfcConfigParameters.SystemIDs, sys)
.Add(RfcConfigParameters.User, user)
.Add(RfcConfigParameters.Password, pass)
.Add(RfcConfigParameters.Client, clie)
.Add(RfcConfigParameters.Language, lang)
End With
Return conf
Catch ex As Exception
Throw New Exception("Falha ao abrir conexão:" & vbCrLf & ex.Message)
End Try
End Function

Public Function IDestinationConfiguration_ChangeEventsSupported() As Boolean Implements IDestinationConfiguration.ChangeEventsSupported
Return True
End Function

Public Function ChangeEventsSupported() As Boolean
Return True
End Function

Public Event ConfigurationChanged As RfcDestinationManager.ConfigurationChangeHandler Implements IDestinationConfiguration.ConfigurationChanged
End Class

Alguns comentários sobre a classe
vejam que o método GetParameters recebe uma variável "destinationName", que é responsável por dizer qual é o servidor SAP que iremos nos conectar. Em nosso exemplo apesar de recuperarmos os dados para acesso de um único lugar, eu simulei o acesso a um servidor de Homologação (Testes) e a um servidor de produção. Com isso através da variável "destinationName" você poderá ter N instancias para N servidores SAP, ok?

Conexão com SAP

'NÃO ESQUEÇA DE IMPORTAR A BIBLIOTECA SAP
Imports SAP.Middleware.Connector

Public Class RfcTableReader
    Public Sub LerDadosRFC()
        Try

            '1º - MONTAR OS PARAMETROS PARA CONEXÃO SAP
            Dim con As New SAPConnect()
            'A FUNÇÃO REGISTER ABRE A CONEXÃO COM SAP
            RfcDestinationManager.RegisterDestinationConfiguration(con)
            'MONTA OS PARAMETROS DO SERVIDOR SAP QUE IREMOS CONECTAR
            Dim dest As RfcDestination = RfcDestinationManager.GetDestination("homologacao")
            Dim repositorio As RfcRepository = dest.Repository
            Try
                'AQUI SEGUE O CÓDIGO FONTE PARA EXECUTAR A RFC
                'LER TABLES
                'GRAVAR TABLES
                'PASSAR PARAMETROS
                '...
            Catch exSap As RfcAbapRuntimeException
                Throw New Exception("ABAP error run Time: " & exSap.Message)
            Catch exSap As RfcAbapBaseException
                Throw New Exception("ABAP base error" & exSap.Message)
            Catch ex As Exception
                Throw
            Finally
                'FECHA A CONEXÃO COM SAP
                RfcDestinationManager.UnregisterDestinationConfiguration(con)
            End Try

        Catch exSap As RfcCommunicationException
            Throw New Exception("Falha na comenicação com SAP: " & exSap.Message)
        Catch exSap As RfcLogonException
            Throw New Exception("Falha no Login: " & exSap.Message)
        Catch ex As Exception
            Throw New Exception("Erro: " & vbCrLf & ex.Message)
        End Try
    End Sub

End Class
Foi utilizado try catch para controlar a conexão, para não deixarmos conexões abertas

No fim deste tutorial eu irei disponibilizar o código fonte para download.

Parte 3

SAP .Net Connector 3.0 - Net Framework 4.0 - Executando uma RFC e lendo os dados de uma tabela

Bem, resolvi escrever esse tutorial pois encontrei poucas informações precisas, e exemplos simples de como executar um RFC e ler os dados de uma tabela do SAP, realizando uma integração do SAP através da plataforna .Net, seja ela em C# ou Vb.Net.

Para isso estarei dividindo o texto em três tópicos básicos:

1. Download das bibliotecas SAPNCO 3.0 e criação de um projeto .Net;
2. Configuração e Conexão de seu projeto com o SAP;
3. Executando uma RFC e lendo os dados de um tabela;

Bem então vamos começar pelo mais simples:

Download das bibliotecas SAPNCO 3.0 e criação de um projeto .Net

Para fazer download das bibliotecas SAP .NET CONNECTOR 3.0 você poderá acessar o site: https://www.nuget.org/packages/SAPDotNetConnector3 e baixar os arquivos mais atuais direto para seu visual Studio através do Package Manager Console.

Para facilitar sua vida eu disponibilizei os arquivos no link [ clique aqui para download ] senha para descompactar o arquivo [ besaleel.blogspot.com.br ]

Com os arquivos em mãos agora precisamos criar nosso projeto, usarei nos exemplos Vb.Net, mas se desejar fazer seu projeto em C# é bem simples.

Criando um projeto Vb.Net

Criei um projeto windows forms de nome Rfc.Tutorial.

OBS importante: para SAP .Net Connector 3.0 que estamos utilizando obrigatoriamente você terá que utilizar a versão do .Net 4.0 do contrário não irá funcionar. 

Reforçando NÃO é a versão 4.0 Client ou a 3.5, ok?

Com o projeto criado iremos agora inserir a referencia das bibliotecas SAP que você baixou no início desse tutorial ( sapnco e sapnco_utils ).

Clique em "Add", no formulário de add Referencia clique em Browser, vá até a pasta lib, que se encontra dentro do arquivo que você baixou, selecione os dois arquivos e clique em "Ok".

Aqui encerramos a primeira parte do Tutorial.

parte 2

Recuperar ação através do clique do mouse com o botão direito dentro do Preactor

    A ideia deste blog é organizar um conjunto de funções que, vira e mexe eu preciso, e quero te-las de fácil acesso.

A função abaixo faz parte de um API Preactor, e é chamada de dentro do quadro de gantt. Ela irá retornar o registro que foi clicado com o Botão direito do mouse, para assim executarmos a ação que o usuário deseja realizar.

Eu costumo utilizar essa função em treinamentos da API do Preactor.

    Public Function GetCustomCheckRecordNumber(ByRef pespComObject As Object) As Integer

        'Cria um novo objeto  Preactor.Interop.EventScripts.Core
        Dim PESP As New Preactor.Interop.EventScripts.Core()

        'Recebe a referência do Objeto
        PESP = CType(pespComObject, Core)

        'Retornando informações da operação alterada
        Return (PESP.CustomCheckRecordNumber)

    End Function

Segue abaixo uma imagem do gráfico de gantt do Preactor.

Ordenando um IList com VB.Net

Bem estou escrevendo esse post por que vira e meche eu preciso desse mesmo comando e eu nunca guardo  a sintaxe do VB.Net. Por que principalmente não gosto dessa linguagem, prefiro o C# Net.

Segue abaixo o modelo de script de ordenação de IList utilizando LINQ

Imports System.Linq


 Dim sortedEnum As IEnumerable(Of OrdemItem) = _ordem.Itens.OrderBy(Function(m) m.Posicao)
 _ordem.Itens = sortedEnum.ToList()

Agora não esqueço mais.

Trabalhando com Arquivos Texto no VB6

Lendo um Arquivo Txt ou CVS

Bem, esse artigo foi escrito por que vira e mexe eu necessito de algumas funções do vb6 para dar manutenção e me deparo com uma linguagem que nem me recordo como funciona ou quais são suas bibliotecas e classes. Esse artigo aborda a leitura e de arquivo texto, seja ele txt, cvs ou log.

Idealização do Algorítimo

Para ficar mais didático separei o algorítimo em 3 partes, primeiro leitura do arquivo texto, segundo separação do arquivo em linhas e por fim, separação das linhas em colunas. Para criei 3 funções básica e bem comentadas.

Criando meu Projeto

Criei um projeto simples, com um form e adicionei um botão para chamar a ação, em seguida fui no menu “Projetos”, “Referências” e adicionei a referência “Microsoft Scripting Runtime”, essa biblioteca que possibilita a leitura do Arquivo, é semelhante a System.IO da plataforma Net.

Arquivo de Leitura

O Arquivo que irei ler esta no padrão, separado por ponto e vírgula, ok, conforme imagem em anexo.

Solução

Segue abaixo as função criadas e comentadas:

Public Function lerArquivo(arquivo As String) As String
    'DEFINIR O OBJETO DE LEITURa
    Dim fso
    Set fso = CreateObject("Scripting.FileSystemObject")
   
    'ABRIR O ARQUIVO ATRAVÉS DO CAMINHO FISICO
    Set arq2 = fso.OpenTextFile("C:\Pastapadrao\" & arquivo, ForReading, True)
   
    'LER OS DADOS DO ARQUIVO
    Dim texto As String
    texto = arq2.ReadAll
    arq2.Close
    'RETORNAR A STRING DO CONTEUDO O ARQUIVO LIDO
    lerArquivo = texto
End Function

Public Sub DividirEmColunas(ByVal arquivo As String)
    'SEPARANDO O ARQUIVO POR LINHAS

   ' vbVrLf ou CHR(13) representam quebra de linha
    Dim LinhasDoArquivo() As String
    LinhasDoArquivo = Split(arquivo, Chr(13)) 

    'PARA QUE A FUNÇÃO SPLIT POSSA FUNCIONAR

    'A DEFINIÇÃO DA VARIAVEL QUE RECEBERÁ SEU VALOR

    'DEVERÁ SER FINALIZADA COM "( )"

    'EXEMPLO SE ELAS ESTIVESSE ASSIM Dim LinhasDoArquivo As String

    'DARIA ERRO
    For i = 0 To UBound(LinhasDoArquivo)

       'CHAMAR FUNCAO PARA LER LINHAS
       TratarLinhas LinhasDoArquivo(i)
    Next
End Sub

Public Sub TratarLinhas(linha As String)
    'DIVIDIR LINHA EM COLUNAS
    Dim colunas() As String
    colunas = Split(linha, ";")
   
    'DEFINIÇÃO DAS COLUNAS
    Dim Codigo As String 'COLUNA 1
    Dim Material As String 'COLUNA 2
    Dim Recurso As String 'COLUNA 3
   
    'ATRIBUIR VALORES
    Codigo = colunas(0)
    Material = colunas(1)
    Recurso = colunas(2)
   
    'APLICAR AÇÃO...
   
End Sub

Bem, em resumo e de forma bem simples é isso!

Nhibernate

Bem, estou escrevendo este post por que estou tendo problemas ao começar estudar o NHibernate. Até onde eu fui, seu uso é simples, as funções principais da bliblioteca já estão bem escritas, deixando o trabalho pesado para ela.


Ao começar a procurar no google referências sobre o assunto eu encontrei inúmeors sites com tutoriais, guias passo a passo, inclusive o site do NHibernate trás uma ótima documentação sobre o assunto. Mas foi um blog que eu encontrei algo simples, e prático e bem direto, mostrando um passo a passo de forma mais breve, sem muita teoria ou porque das coisas, ele esta dividido em duas partes, Parte 01 que nada mais é que uma pequena introdução, e Parte 02, os mapeamentos e sua primeira implementação, e configurações.

 

Bem, essa imagem acima foi a minha primeira dificuldade encontrada, que nada mais foi que Referências a Dlls. Como eu havia copiado as dlls para dentro do projeto e depois add nas referências isso causou um erro interno, e o projeto não estava encontrando as dlls (NHibernate.ByteCode.Castle.ProxyFactoryFactory, NHibernate.ByteCode.Castle). A resolução do problema foi bem simples, o que fiz foi criar uma nova pasta fora do projeto com todas as Dlls usadas no projeto, e ao fazer as referencias, fazia desta pasta.




Bem, em resumo percebi que o Nhibernate é bem simples e fácil de usar, é como seguir uma receita de bolo, seguindo os passos padrão, não há erro.




Bem segue em anexo meu projeto teste.

abraço.